从C调用FORTRAN子例程

fortRoutine_("I am in fortran");

现在要做的就是在Fortran端使用Fortran ISO C Binding.这是Fortran 2003语言标准的一部分,并且可以在许多编译器中使用;它不是具体的gcc.这个网站已经在很多答案中描述过了.作为语言标准的一部分,它是编译器和平台无关的.并且您不需要知道编译器的内部传递约定. ISO C Binding在声明Fortran子程序或函数时使用时,会导致Fortran编译器使用C调用约定,以便可以从C直接调用该过程.您不需要添加隐藏的参数或命名mangle Fortran子例程名称,即没有下划线.链接器使用的名称来自“绑定”选项.

字符串是一个困难的情况,因为技术上在C它们是字符数组,你必须匹配在Fortran.您还必须处理字符串的不同定义：C为空终止,Fortran固定长度并填充空白.该示例显示了如何工作.数字更容易数组的唯一问题是C是行主和Fortran列主要,以便多维数组被转置.

int main ( void ) {

   char test [10] = "abcd";

   myfortsub (test);

   return 0;

}

和

subroutine myfortsub ( input_string ) bind ( C,name="myfortsub" )

   use iso_c_binding,only: C_CHAR,c_null_char
   implicit none

   character (kind=c_char,len=1),dimension (10),intent (in) :: input_string
   character (len=10) :: regular_string
   integer :: i

   regular_string = " "
   loop_string: do i=1,10
      if ( input_string (i) == c_null_char ) then
         exit loop_string
      else
         regular_string (i:i) = input_string (i)
      end if
   end do loop_string

   write (*,*) ">",trim (regular_string),"<",len_trim (regular_string)

   return

end subroutine myfortsub

您将C编译为对象文件,并使用gfortran编译fortran并链接两者：

gcc-mp-4.6   \
         -c  \
         test_fortsub.c

gfortran-mp-4.6   \
     test_fortsub.o  \
     myfortsub.f90  \
     -o test_fortsub.exe

输出为：

>abcd<           4